DigiNG edición Scripting

Código de ejemplo "Poligono"

El código de este ejemplo registra un polígono cerrado con un número determinado de lados especificados por el usuario mediante un InputBox de VBScript.

Para ejecutar este código en DigiNG, seguir los siguientes pasos:

Crear con un editor de textos (como el bloc de notas) un archivo llamado "Poligono". Posiblemente, al salvar el archivo el editor de textos utilizado le añada la extensión .txt, que tendremos que quitar más adelante con el explorador de archivos de Windows.

Copiar el siguiente bloque de código de ejemplo en el archivo "CargaDatos".

Const Pi = 3.14159265358979323846

Dim lados

lados = InputBox("Número de lados")

If lados < 3 Then

    MsgBox "El número de lados debe ser tres o superior", vbOKOnly, "Error"

Else

    Dim ptCentro

    Dim ptPrimerVertice

    digi.ImprimeMensaje "Digitalize el centro del polígono..."

    Set ptCentro = digi.PidePunto

    digi.ImprimeMensaje "Digitalize un vértice del polígono..."

    Set ptPrimerVertice = digi.PidePunto

    digi.ImprimeMensaje ""

    Dim distancia

    distancia = ptCentro.Distancia(ptPrimerVertice)

    Dim angulo

    angulo = ptCentro.Angulo(ptPrimerVertice)

    Dim puntoCalculado

    Set puntoCalculado = CreateObject("Digi3D.Point")

    puntoCalculado.z = ptPrimerVertice.z

    Dim linea

    Set linea = CreateObject("Digi3D.Entidad")

    linea.Codigo = digi.Codigo

    Dim i

    For i = 1 To lados

        puntoCalculado.x = ptCentro.x + distancia * Cos( angulo + (i-1)*2*Pi/lados )

        puntoCalculado.y = ptCentro.y + distancia * Sin( angulo + (i-1)*2*Pi/lados )

        linea.AnadePunto(puntoCalculado)

    Next

    linea.Cerrar

    digi.DibujaEntidad(linea)

    digi.AnadeEntidad(linea)

    ' Liberamos la memoria

    Set puntoCalculado = Nothing

    Set ptCentro = Nothing

    Set ptPrimerVertice = Nothing

End If

Mirar también

Método ImprimeMensaje | Método PidePunto | Método DibujaEntidad | Método AnadeEntidad | Propiedad Codigo | Objeto Point | Objeto Entidad

Fecha de última modificación: domingo, 9 de diciembre de 2001

© 2001 Dreaming With Objects. Todos los derechos reservados.